REXX Tips & Tricks, Version 2.80


Inf-HTML [About][Toc][Index] 0.9b (c) 1995 Peter Childs


Get icons from the OS2.INI file



Use the following program to get the icons saved in the file OS2.INI (see 
also Icon resources in default OS/2 DLLs and Extract the icon from the 
EAs): 

 
/*                                                                    */
/* Name:     GetWICO.CMD                                              */
/*                                                                    */
/* Function:                                                          */
/*   sample program to get the icons from the OS2.INI file            */
/*                                                                    */
/* Usage:                                                             */
/*   GetWICO                                                          */
/*                                                                    */
/* Where:                                                             */
/*   -                                                                */
/*                                                                    */
/* Returns:                                                           */
/*   -                                                                */
/*                                                                    */
/* Credits:                                                           */
/*   -                                                                */
/*                                                                    */
/* History:                                                           */
/*   18.01.1996 /bs                                                   */
/*     - initial release for RXT&T v2.00                              */
/*                                                                    */
/* Notes:                                                             */
/*                                                                    */
/*   The .ICO files are created in the current directory.             */
/*                                                                    */
/*   Tested only with WARP.                                           */
/*                                                                    */
/*                                                                    */
/* (c) 1996 Bernd Schemmer, Germany, EMail: 100104.613@compuserve.com */
/*                                                                    */

                        /* load REXXUTIL function                     */
  call rxFuncAdd "SysIni", "REXXUTIL", "SysIni"

  say "GetWICO - get the icons from the OS2.INI file"

                        /* get a list of the icons                    */
  call SysIni "USER", "PM_Abstract:Icons", "ALL:" , "icons."

  call CharOut,  "Creating " || icons.0 || " .ICO files "

  do i = 1 to icons.0
    curIconFile = "ICO_" || icons.i || ".ICO"

    call CharOut , "."
    call stream curIconFile, "c", "OPEN WRITE"

    call CharOut curIconFile ,,
                 sysIni( "User", "PM_Abstract:Icons", icons.i )

    call stream curIconFile, "c", "CLOSE"
  end /* do i = 1 to icons.0 */
  call LineOut , " done."

exit 0

  

Inf-HTML End Run - Successful